J House Consulting

Citrix Community Featured Web Page

jeremy — Wed, 16 Dec 2009 09:49:40 +0000

I was stoked to find out that my web site has been listed on the Citrix Community Featured Web Page How cool is that?

VDI and Storage: Deep Impact

jeremy — Fri, 11 Dec 2009 01:00:44 +0000

AWESOME document!!! This is a MUST read.

http://virtuall.eu/download-document/vdi-storage-deep-impact

Ruben Spruijt blogged about it on Brian Madden’s web site, and received a lot of great comments worth reading.

Here is the PDF incase the link above does not work: VDI_and_Storage_-_Deep_Impact-v1.0.pdf

Since the release of this document, there has been some fantastic comments and blogs posted around this subject:

Cheers,

Jeremy.

Installing the HP Universal Print Drivers on Citrix/Terminal Servers

jeremy — Wed, 09 Dec 2009 14:28:59 +0000

I have found the latest batch of HP’s Universal Printer Drivers to be the very stable. The command line I use for installing the HP Universal Print Drivers on Citrix/Terminal servers is as follows:

Version 5.0 PCL 5

install.exe /q /npf /nd /dod /dos /dpm /ddu /dso /gdssnp /snptm=0 /dm /dmpa /dads /pqdmpa /pqdads

Version 5.0 PCL 6

install.exe /q /npf /nd /dod /dos /dpm /ddu /dso /gdssnp /snptm=0 /dm /dmpa /dads /pqdmpa /pqdads

Version 5.0 PS (Post Script)

install.exe /q /npf /nd /dod /dos /dpm /ddu /dso /gdssnp /snptm=0 /dm /dmpa /dads /pqdmpa /pqdads

Where…

/q – Quite mode, no prompts
/npf - Do not open the Printers folder on completion
/nd - Does not set the printer as the default
/dod - Disables the Online Diagnostic option on the Services tab in the HP UPD
/dos - Disables the Online Support option on the Services tab in the HP UPD
/dpm - Disables the Online Product Manual option on the Services tab in the HP UPD
/ddu - Disables the Online Driver Updates option on the Services tab in the HP UPD
/dso - Disables the Online Supplies Ordering option on the Services tab in the HP UPD
/gdssnp – Disables the Status Notification Pop-ups for all printers
/snptm=0 - Disables the Special Offers program pop–ups
/dm - Installs the printer in dynamic mode
/dmpa - Disables HP MPA policy checking for current user
/dads - Disables ADS policy checking for current user
/pqdmpa - Disables MPA policy checking for the current print queue (logical windows printer) no matter who uses it
/pqdads - Disables ADS policy checking for the current print queue (logical windows printer) no matter who uses it

Three printers will then appear in “Printers and Faxes” as per the screenshot below.

The following commands will remove the printers ONLY, leaving the drivers behind.

rundll32 printui.dll,PrintUIEntry /dl /n “HP Universal Printing PCL 5″

rundll32 printui.dll,PrintUIEntry /dl /n “HP Universal Printing PCL 6″

rundll32 printui.dll,PrintUIEntry /dl /n “HP Universal Printing PS”

I hope that helps!

My First Stand-up Comedy Experience

jeremy — Mon, 07 Dec 2009 17:30:31 +0000

As an IT Geek, I’m very much an introvert, or as I like to say, an introverted extrovert One of my personal goals in life is to do Improvisation Comedy also known as Theatre Sports. It’s awesome fun, and extremely funny when you’ve got the right mix of people and personalities playing off each other. In preparing myself for this by helping to bring out the extrovert within, and to understand the pressures of not only performing in front of a live audience, but also making them laugh, I completed a Stand-up Comedy workshop run by a very funny and clever man by the name of Robert Grayson.

The workshop was so much fun. You learn the art of how to write comedy, how to find the right subjects to speak about, and how to relate to the audience. It teaches you about “being in the moment”. But most importantly for me, I learnt how to deal with the negative demons within, and go far beyond my comfort zone to a point I never throught I’d ever reach.

As part of the graduation I appeared live on stage at Lazy Susan’s Comedy Den (Brisbane Hotel) back on 8th November. It was an amazing night. I was on such a high for days afterwards. Here is a video of my performance.

Here are a couple of group photos from the night.

There is heaps of awesome comedy in Perth that you can see almost every night of the week. But for me, the piece de resistance is the Big Hoo Haa on Saturday Nights upstairs at the Brisbane Hotel in Lazy Susan’s Comedy Den. So much raw talent on stage. Maybe one day I will be part of that team!

Cheers,

Jeremy.

How to prevent certain MS Outlook dialog boxes from showing?

jeremy — Sun, 06 Dec 2009 04:27:09 +0000

This script will manage the “PONT_STRING” registry value to control the “Don’t Show Dialog” Setting for some of the Outlook dialog boxes that don’t have a simple way of preventing them from showing via a Group Policy Setting, etc. Under Outlook 2007 there are two particular dialog boxes that may prompt the user when a new profile is created.

This script will prevent them from showing.

These options are held under the following key…

HKEY_CURRENT_USER\Software\Microsoft\Office\xx.0\Outlook\Options\General

…where xx is the Office version number.

Enjoy!

MSOutlookDialogs.vbs

' This script will manage the "PONT_STRING" registry value to control the "Don't Show
' Dialog" Setting" for some of the Outlook dialog boxes that don't have a simple way
' of preventing them from showing via a Group Policy Setting, etc.
'
' These options are held under the following key...
' HKEY_CURRENT_USER\Software\Microsoft\Office\xx.0\Outlook\Options\General
' where xx is the Office version number.
'
' Note that the "PONT_STRING" string must end with a comma.
'
' Simply set all Office versions you are using in the arrVersions array and the 
' dialogs you want to prevent from displaying in the arrDialogs array.
'
' Release 1.0
' Written by Jeremy@jhouseconsulting.com on 6th December 2009.
'
Option Explicit

Dim arrVersions, arrDialogs, objShell, Version, strKeyRoot, strKeyPath
Dim Dialog, strValueData, arrValueData, BlnReturn
'
arrVersions = Array("12.0")
' Note that...
' - Office 2000 = 9.0
' - Office XP/2002 = 10.0
' - Office 2003 = 11.0
' - Office 2007 = 12.0
'
arrDialogs = Array("60","48")
' 60 - "Windows Desktop Search is not currently installed or not up to date. Outlook
'       will not be able to provide fast search results when using the new Instant
'       Search functionality unless this Windows component is installed. Please contact
'       your system administrator."
' 48 - "Outlook, Windows Internet Explorer, and other applications save lists of RSS
'       Feeds that you subscribe to. The Common Feed List in Microsoft Windows
'       maintains one synchronized list of RSS Feeds. Do you want your RSS Feeds in
'       Outlook to be synchronized with the Common Feed List?"
'
Set objShell = WScript.CreateObject("WScript.Shell")

strKeyRoot = "HKCU\"
strKeyPath = "Software\Microsoft\Office\"

If IsArray(arrVersions) AND IsArray(arrDialogs) Then
  For Each Version in arrVersions
    strKeyPath = strKeyPath & Version & "\Outlook\Options\General\"
    If RegValueExists(strKeyRoot & strKeyPath & "PONT_STRING") Then
      strValueData = objShell.RegRead(strKeyRoot & strKeyPath & "PONT_STRING")
      arrValueData = Split(strValueData,",")
      For Each Dialog in arrDialogs
        BlnReturn = InArray(Dialog,arrValueData)
        If NOT BlnReturn Then
          strValueData = strValueData & Dialog & ","
        End If
      Next
    Else
      For Each Dialog in arrDialogs
        strValueData = strValueData & Dialog & ","
      Next
    End If
    objShell.RegWrite strKeyRoot & strKeyPath & "PONT_STRING", strValueData
  Next
End If

Set objShell = Nothing

wscript.quit(0)

Function RegValueExists(sRegValue)
' Returns True or False based of the existence of a registry value.
  Dim oShell, RegReadReturn 
  Set oShell = CreateObject("WScript.Shell") 
  RegValueExists = True  ' init value 
  On Error Resume Next 
  RegReadReturn = oShell.RegRead(sRegValue) 
  If Err.Number <> 0 Then 
    RegValueExists = False 
  End if 
  On Error Goto 0 
  Set oShell = Nothing
End Function 

Function InArray(item,myarray)
  Dim i
  For i=0 To UBound(myarray) Step 1
    If lcase(item)=lcase(myarray(i)) Then
      InArray=True
      Exit Function
    End If
  Next
  InArray=False
End Function

WAN Emulation for VDI and SBC Testing

jeremy — Sun, 29 Nov 2009 02:17:10 +0000

WANem (Wide Area Network Emulation) is an awesome tool for emulating a WAN in your test/dev environment or even a demo lab. I use it in my demo lab to show customers how the technologies might behave in their environment.

WANem is a piece of software running on Knoppix, a well-known Linux distribution based on Debian. It comes in two forms:

As an ISO that is launched through a LiveCD at computer startup.
As a VMware Virtual Appliance that can be launched from a VMware platform.

You can get WANem from here: http://wanem.sourceforge.net/

Since my lab runs multiple hypervisors I found it too complex to build the switching and routing required to implement it as a virtual appliance, so I acquired an old PC and purchased a 2nd network card. This gives me the flexibility needed to implement it as needed.

For ease of implementation I implement it in Bridge mode. Unfortunately Bridge mode does not support all the nice Advanced Mode features, but it does enable you to set the bandwidth and latency (delay) from within the Basic Mode configuration page.

An advantage with Bridge mode is that it will automatically pass through DHCP broadcasts. This is a drawback if running WANem as a router because the current implementation of WANem does not contain the dhcp-helper package, and as of version 2.2, there is currently no way to add it because it is launched through a LiveCD at computer startup, unless of course you use the VMware virtual appliance. As of version 2.2 WANem cannot be installed on a hard drive. This should be possible in a future releases, which will then mean that additional packages can be added, such as the dhcp-helper package, etc.

The following notes were collated from here:

To configure the WANem as a Bridge

When the WANem first boots…

It will ask if you want to configure all interfaces via DHCP. Type y and hit Enter.
Enter a new UNIX password. (Enter the password of your choice.)
Retype the new UNIX password.
You will need the password if you want to remotely access the Knoppix Linux platform via SSH.

Once it has completed its initialisation, type exit2shell to drop out to the knoppix shell.

To configure, type the following commands:

# Remove any existing IP configuration and bring up all the interfaces:
ifconfig eth0 0.0.0.0 up
ifconfig eth1 0.0.0.0 up

# Create the Bridge-group interface called br0
brctl addbr br0

# Add each interface to the bridge-group br0
brctl addif br0 eth0
brctl addif br0 eth1

# Set an ip address to the bridge-group br0 for management
ifconfig br0 10.0.160.200 netmask 255.255.255.0

# Add a default Route so that it can be managed from another network
route add default gw 10.0.160.5

Now ping a device on your network to test connectivity.

Type wanem to restart the WANem tool.

To manage the WANem, connect to it via HTTP:
http://10.0.160.200/WANem

You can also access the Knoppix/Linux level with SSH.
The username is “perc” and the password is what was previously set at the end of the Knoppix boot process.

WANem CLI (Command Line Interface):

The “help” command provides the available commands list:

WANemControl@PERC>help
help — Displays this help.
about — About WANem
clear — Clear the Screen
reset — Reset the network setting and services
shutdown — Shutdown the System
restart — Restart the System
status — Check the status of Network settings and services
wanemreset — Reset WANem settings from here if GUI is very slow
assign — Assign an IPAddress to a device usage:assign
quit — Quit the shell

So as you can see, it so simple to implement and use, and works really well.

Cheers,

Jeremy.

Deployment Script for Citrix Profile Management 2.x

jeremy — Sat, 28 Nov 2009 19:11:24 +0000

Here is my deployment script for Citrix Profile Management 2.x, formerly known as User Profile Manager.

Enjoy!

InstCPM.cmd

@Echo Off
Echo Citrix XenApp Deployment
Echo ------------------------
Echo.
Echo Revision History:
Echo.
Echo v1.0 07/09/09 Jeremy@jhouseconsulting.com
Echo Updated for Citrix Profile Management 2.0.1
Echo.
Echo ....Installing Citrix Profile Management 2.x.....
Echo.
Echo.

SetLocal

Set CPMVersion=2.0.1

Set CPMInstaller=profilemgr2_x86.msi
IF /I "%PROCESSOR_ARCHITECTURE%"=="AMD64" Set CPMInstaller=profilemgr2_x64.msi

Set loglocation=%systemDrive%\bldlogs
if not exist %loglocation% md %loglocation%

IF EXIST %SYSTEMROOT%\SYSTEM32\CHANGE.EXE CHANGE USER /INSTALL

:: Installing CPM...
start "Installing..." /wait msiexec /i "%~dp0%CPMVersion%\%CPMInstaller%" /qb /Lv* "%loglocation%\CPM%CPMVersion%.log" REBOOT=ReallySuppress

IF EXIST %SYSTEMROOT%\SYSTEM32\CHANGE.EXE CHANGE USER /EXECUTE

:: Enable Citrix Profile Management by setting the following registry value. This can be done by
:: using the supplied Administrative Template in a Group Policy Object (GPO).
:: Key: HKLM\Software\Policies\Citrix\UserProfileManager
:: Value: ServiceActive
:: Type: REG_DWORD
:: Data: 1

:: We rename the ini files as a precautionary measure. This is because the ini file contains the
:: default entries for all settings that are configurable via group policy. The issue here is
:: that once the Citrix User Profile Manager service has been enabled, if the corresponding group
:: policy setting is set to "not configured", it will use the default setting in the ini file.
:: This can be dangerous! Hence the reason why we rename it by default.
If EXIST "%PROGRAMFILES%\Citrix\User Profile Manager\UPMPolicyDefaults_V1Profile_en.ini" (
REN "%PROGRAMFILES%\Citrix\User Profile Manager\UPMPolicyDefaults_V1Profile_en.ini" "UPMPolicyDefaults_V1Profile_en.ini.old"
)
If EXIST "%PROGRAMFILES%\Citrix\User Profile Manager\UPMPolicyDefaults_V2Profile_all.ini" (
REN "%PROGRAMFILES%\Citrix\User Profile Manager\UPMPolicyDefaults_V2Profile_all.ini" "UPMPolicyDefaults_V2Profile_all.ini.old"
)

EndLocal
Exit /b 0

User-Self Help Tools for an SBC and VDI Deployment

jeremy — Sat, 28 Nov 2009 18:53:40 +0000

Whenever I implement a Citrix/Terminal Server farm, I always include certain applications and tools that I believe users will get some value from, which may in-turn assist IT Support by lowering the number of helpdesk calls. Who knows???

I have blogged about all these tools before…

Their Start Menu shortcuts can be seen in the screenshot below.

You can download them all in one zip file from here: userself-helptools

Execute the following scripts to install them:

InstallCtrlAltDelITConsultancySelfHelpTools.cmd
InstallConvert.cmd
InstallRepairClipboardChain.cmd

I hope you find this useful.

Cheers,

Jeremy.

Deployment Script for the very cool Convert utility

jeremy — Sat, 28 Nov 2009 18:12:57 +0000

Here is a deployment script for the very cool convert.exe utility from Josh Madison.

Enjoy!

InstallConvert.vbs

' Installation script for convert.exe (http://www.joshmadison.com/software)
'
' Notes:
' 1) Even though this a a 32-bit application...
'    i) It will still run 100% correctly in a 64-bit environment.
'    ii) In a 64-bit environment we deploy it to the "%ProgramFiles%"
'        location and not the "%ProgramFiles(x86)%" location. This provides
'        a single location for the published application regardless of the
'        system architecture type.
'
' Revision 1.2 on 21st October 2009.
' Written by Jeremy@jhouseconsulting.com on 30th December 2008.
'
Option Explicit

Dim objfso, objFolder, wshShell, oShellLink, strAUPrograms, strAUDesktop
Dim strProgramFiles, strScriptPath, blnStartMenuShortcut, blnDesktopShortcut

blnStartMenuShortcut = True
blnDesktopShortcut = False

set WshShell = WScript.CreateObject("WScript.Shell")
set objfso = CreateObject("Scripting.FileSystemObject")

strProgramFiles = WshShell.ExpandEnvironmentStrings("%ProgramFiles%")
strAUPrograms = WshShell.SpecialFolders("AllUsersPrograms")
strAUDesktop = WshShell.SpecialFolders("AllUsersDesktop")
strScriptPath = Left(WScript.ScriptFullName, InstrRev(WScript.ScriptFullName, "\"))

If objFSO.FileExists(strScriptPath & "Convert.exe") Then
  If NOT objFSO.FolderExists(strProgramFiles & "\JoshMadison") Then
    Set objFolder = objFSO.CreateFolder(strProgramFiles & "\JoshMadison")
  End If
  If NOT objFSO.FolderExists(strProgramFiles & "\JoshMadison\convert") Then
    Set objFolder = objFSO.CreateFolder(strProgramFiles & "\JoshMadison\convert")
  End If
  objFSO.CopyFile strScriptPath & "Convert.exe", strProgramFiles & "\JoshMadison\convert\", True
  If blnStartMenuShortcut Then
    Set oShellLink = WshShell.CreateShortcut(strAUPrograms & "\Convert.lnk")
    oShellLink.TargetPath = chr(34) & strProgramFiles & "\JoshMadison\convert\convert.exe" & chr(34)
    oShellLink.WorkingDirectory= strProgramFiles & "\JoshMadison\convert"
    oShellLink.IconLocation = strProgramFiles & "\JoshMadison\convert\convert.exe" & ",0"
    oShellLink.Save
  End If
  If blnDesktopShortcut Then
    Set oShellLink = WshShell.CreateShortcut(strAUDesktop & "\Convert.lnk")
    oShellLink.TargetPath = chr(34) & strProgramFiles & "\JoshMadison\convert\convert.exe" & chr(34)
    oShellLink.WorkingDirectory= strProgramFiles & "\JoshMadison\convert"
    oShellLink.IconLocation = strProgramFiles & "\JoshMadison\convert\convert.exe" & ",0"
    oShellLink.Save
  End If
End If

Set WshShell = Nothing
Set objfso = Nothing
Set objFolder = Nothing
Set oShellLink = Nothing

WScript.Quit(0)

Deployment Script for the Repair Clipboard Chain utility

jeremy — Sat, 28 Nov 2009 17:56:33 +0000

Here is a deployment script for the Citrix Repair Clipboard Chain (RepairCBDChain.exe) utility as per Citrix KB article CTX106226.

This utility does not have a nice default icon, so I have used this one.

Enjoy!

InstallRepairClipboardChain.vbs

' Installation script for the Repair Clipboard Chain utility as per Citrix KB article CTX106226
'
' Notes:
' 1) Even though this a a 32-bit application...
'    i) It will still run 100% correctly in a 64-bit environment.
'    ii) In a 64-bit environment we deploy it to the "%ProgramFiles%"
'        location and not the "%ProgramFiles(x86)%" location. This provides
'        a single location for the published application regardless of the
'        system architecture type.
'
' Revision 1.0
' Written by Jeremy@jhouseconsulting.com on 10th November 2009.
'
Option Explicit

Dim objfso, objFolder, wshShell, oShellLink, strAUPrograms, strAUDesktop
Dim strProgramFiles, strScriptPath, blnStartMenuShortcut, blnDesktopShortcut
Dim strStartMenuSubFolder, strStartMenuFolder

blnStartMenuShortcut = True
blnDesktopShortcut = False
strStartMenuSubFolder = "User Self-Help Tools"

set WshShell = WScript.CreateObject("WScript.Shell")
set objfso = CreateObject("Scripting.FileSystemObject")

strProgramFiles = WshShell.ExpandEnvironmentStrings("%ProgramFiles%")
strAUPrograms = WshShell.SpecialFolders("AllUsersPrograms")
strAUDesktop = WshShell.SpecialFolders("AllUsersDesktop")
strScriptPath = Left(WScript.ScriptFullName, InstrRev(WScript.ScriptFullName, "\"))

If objFSO.FileExists(strScriptPath & "RepairCBDChain.exe") AND objFSO.FileExists(strScriptPath & "clipboard.ico") Then
  If NOT objFSO.FolderExists(strProgramFiles & "\Citrix") Then
    Set objFolder = objFSO.CreateFolder(strProgramFiles & "\Citrix")
  End If
  objFSO.CopyFile strScriptPath & "RepairCBDChain.exe", strProgramFiles & "\Citrix\", True
  objFSO.CopyFile strScriptPath & "clipboard.ico", strProgramFiles & "\Citrix\", True
  If blnStartMenuShortcut Then
    If strStartMenuSubFolder <> "" Then
      strStartMenuFolder = strAUPrograms & "\" & strStartMenuSubFolder
      If NOT objFSO.FolderExists(strAUPrograms & "\" & strStartMenuSubFolder) Then
        Set objFolder = objFSO.CreateFolder(strAUPrograms & "\" & strStartMenuSubFolder)
      End If
    Else
      strStartMenuFolder = strAUPrograms
    End If
    Set oShellLink = WshShell.CreateShortcut(strStartMenuFolder & "\Repair Clipboard Chain.lnk")
    oShellLink.TargetPath = chr(34) & strProgramFiles & "\Citrix\RepairCBDChain.exe" & chr(34)
    oShellLink.WorkingDirectory= strProgramFiles & "\Citrix"
    oShellLink.IconLocation = strProgramFiles & "\Citrix\clipboard.ico" & ",0"
    oShellLink.Save
  End If
  If blnDesktopShortcut Then
    Set oShellLink = WshShell.CreateShortcut(strAUDesktop & "\Repair Clipboard Chain.lnk")
    oShellLink.TargetPath = chr(34) & strProgramFiles & "\Citrix\RepairCBDChain.exe" & chr(34)
    oShellLink.WorkingDirectory= strProgramFiles & "\Citrix"
    oShellLink.IconLocation = strProgramFiles & "\Citrix\clipboard.ico" & ",0"
    oShellLink.Save
  End If
End If

Set WshShell = Nothing
Set objfso = Nothing
Set objFolder = Nothing
Set oShellLink = Nothing

WScript.Quit(0)